安美资源网

第二章 数组

2.4 Filter函数

Filter函数功能与autofilter函数类似，它对一个一维数组进行筛选，返回一个从0开始的数组。

Filter函数语法：

Filter(sourcearray,match,[include,[compare]])

Filter函数的4个参数，前两个为必选，后两个为可选。

sourcearray：待筛选的一维数组

match：要筛选的字符串

include：true包含（默认），false不包含，对应Excel筛选“文本筛选”里的包含和不包含

compare：0 区分大小写（默认），1 不区分大小写

例句：

Sub tt()

arr = Array("A", "AB", "CDE", "AC", "ab", "ec")

brr = Filter(arr, "A")

'从arr数组里筛选出包含“A”的数组，筛选出“A”、“AB”、“AC”

crr = Filter(arr, "A", False)

'从arr数组里筛选出不包含“A”的数组，筛选出“CDE”、“ab”、“ec”

drr = Filter(arr, "A", , 1)

'从arr数组里筛选出包含“A”的数组，不区分大小写，筛选出“A”、“AB”、“AC”、“ab”

End Sub

筛选结果如下图所示：

需要注意的是，Filter函数只能进行模糊筛选，不能进行精确匹配。在使用过程中，有可能会筛选出自己不需要的数据。所以使用前，先看一下源数据的构成，选出一个更准确的要筛选的字符串。

小程序：从下表中找出B列比A列多的数据，复制到C列。

Sub 找不同()

arr = Application.Transpose(Range("a1:a13"))

brr = Application.Transpose(Range("b1:b28"))

For i = 1 To UBound(arr)

brr = Filter(brr, arr(i), False)

Next

Range("c1").resize(UBound(brr) + 1, 1) = Application.Transpose(brr)

End Sub

把A列数据转换后生成一个一维数组arr,把B列数据转换后生成一个一维数组brr,然后对brr数组进行筛选，筛选出不包含arr数组数值的，然后再赋值给brr数组。

需要注意的是，这个小程序里的brr数组，生成的时候它的下标是从1开始的，用Filter函数筛选后变成了从0开始了，所以粘贴时行数要用UBound(brr) + 1。

执行后的结果是这样的：

Filter函数还可以与Split与Join语句相结合，对一片区域进行筛选操作。把一行数据用Join语句连接成一个字符串赋值给数组的一个元素，用Filter筛选后，再用Split语句把数据拆分开。比如要对下面区域进行筛选：

Sub filter数组筛选()

Dim arr()

For Each ss In Range("a2", [a2].End(xlDown))

n = n + 1

ReDim Preserve arr(1 To n)

arr(n) = Join(WorksheetFunction.Transpose(WorksheetFunction.Transpose(ss.resize(1, 5))), "/")

Next

End Sub

把ss.resize(1, 5)区域，也就是一行数据，两次转换后用Join函数连接成一个字符串，再赋值给arr(n)，这样循环下来，就生成了一个一维数组，接下来就可以用Filter函数进行筛选啦！

brr = Filter(arr, "筛选字段")，比如可以让用户录入一个数值，用数值来筛选符合条件的内容。

筛选出来的结果用Split函数再把它拆分开来：

ReDim crr(1 To UBound(brr) + 1)

For Each x In brr

k = k + 1

crr(k) = Split(x, "/")

Next

拆分后的crr数组是一个嵌套数组，用Transpose函数进行两次转换就可以变成一个正常的二维数组，就会得到你想要的筛选结果了。

往期精彩回顾：

学习VBA，报表做到飞 第二章 数组 2.3 Split与Join

学习VBA，报表做到飞 第二章 数组 2.2 数组的上界与下界

学习VBA，报表做到飞 第二章 数组 2.1 数组的声明、赋值及读取

我是云飞扬，职场财会人员，愿与大家分享表格制作和数据统计分析的技巧与方法，希望大家的工作更便捷，更轻松！